【ExcelVBA】ExcelシートをPDF出力する方法（ExportAsFixedFormat）

9月 2, 20224月 14, 2023

ExcelVBAでExcelシートをPDFに出力したい人向けに書いています。

1. 本記事の内容
2. ExcelVBAでExcelシートをPDF出力する方法
3. まとめ

本記事の内容

・ExcelVBAでExcelシートをPDF出力する方法

ExcelVBA（マクロ）でExcelシートのデータをPDF出力したいと思ったことはありませんか？
請求書等の書類作成を自動作成してPDF出力したいと思っていませんか？
ExcelVBAでExcelシートをPDF出力する方法を紹介します。

ExcelVBAでExcelシートをPDF出力する方法

以下がExcelVBAでExcelシートのデータをPDF出力するプログラムです。

'＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
'＊　PDFファイル出力
'＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
Sub PDF_FILE_OUT()
   
    Dim fileName As String '保存先フォルダパス＆ファイル名
    
    Dim OUT_FOLDER_PATH As String   'PDF出力フォルダパス
    Dim OUT_FILE_NM As String       'PDF出力ファイル名
    Dim OUT_SHEET As String         'PDF出力シート
    
    'PDF出力フォルダパス
    OUT_FOLDER_PATH = ThisWorkbook.Path & "\PDF出力"
    'PDF出力ファイル名
    OUT_FILE_NM = "PDF出力.pdf"
    'PDF出力シート
    OUT_SHEET = "Sheet1"
    
    'PDF出力フォルダがなければ作成する
    If Dir(OUT_FOLDER_PATH, vbDirectory) = "" Then
        MkDir OUT_FOLDER_PATH
    End If
    
    'PDF出力ファイルパス
    fileName = OUT_FOLDER_PATH & "\" & OUT_FILE_NM
   
    '出力ページ設定
    With ThisWorkbook.Sheets(OUT_SHEET).PageSetup
        
        '印刷時の拡大・縮小率を指定する
        .Zoom = False
        '横方向を指定(1)ページ数に収める
        .FitToPagesWide = 1
        '縦方向を指定(1)ページ数に収める
        .FitToPagesTall = 1
        '水平方向に余白を調整して中央寄せ
        .CenterHorizontally = True
        '垂直方向に余白を調整して中央寄せ
        .CenterVertically = True
        
    End With
   
   'PDF出力
    ThisWorkbook.Sheets(OUT_SHEET).ExportAsFixedFormat Type:=xlTypePDF, fileName:=fileName
   
End Sub