【VBA】WebページのファイルをXMLHTTPRequestを使用してダウンロードする方法

6月 19, 20224月 14, 2023

VBAでWebページのファイルをダウンロードしたい人向けに書いています。

1. 本記事の内容
2. WebページのファイルをXMLHTTPRequestを使用してダウンロードする方法
3. まとめ

本記事の内容

・WebページのファイルをXMLHTTPRequestを使用してダウンロードする方法

VBA（マクロ）で自動的にWebページのファイルをダウンロードしたいと思っていませんか？
Webページのファイルをダウンロードする方法を紹介します。

WebページのファイルをXMLHTTPRequestを使用してダウンロードする方法

以下がWebページのファイルをXMLHTTPRequestを使用してダウンロードするプログラムです。

'＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
'＊　Webページファイルダウンロード　XMLHTTPRequest
'＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
Public Sub WEB_PAGE_FILE_DL()
    
    'ダウンロード(引数1：URLファイルアドレス,引数2：保存先ファイルパス)
    DownloadFile "https://msedgedriver.azureedge.net/102.0.1245.44/edgedriver_win64.zip", _
                "D:\Webページ保存ファイル\edgedriver_win64.zip"
    
    MsgBox "処理が完了しました。", vbInformation + vbSystemModal
    
End Sub
  
Private Sub DownloadFile(ByVal Url As String, ByVal SaveFilePath As String)
    
    Dim req As Object
    Const adTypeBinary = 1
    Const adSaveCreateOverWrite = 2
    
    'XMLHTTPRequest
    Set req = CreateObject("Msxml2.XMLHTTP")
    req.Open "GET", Url, False
    
    'キャッシュ対策
    req.setRequestHeader "Pragma", "no-cache"
    req.setRequestHeader "Cache-Control", "no-cache"
    req.setRequestHeader "If-Modified-Since", "Thu, 01 Jun 1970 00:00:00 GMT"
    
    req.Send
    Select Case req.Status
        Case 200
            'ADODB.Streamファイルダウンロード
            With CreateObject("ADODB.Stream")
            .Type = adTypeBinary
            .Open
            .Write req.responseBody
            .SaveToFile SaveFilePath, adSaveCreateOverWrite
            .Close
        End With
        Case Else
            MsgBox "エラーが発生しました。" & vbCrLf & _
                "ステータスコード：" & req.Status, _
                vbCritical + vbSystemModal
        Exit Sub
    End Select
    
End Sub